引用:

公式名称: 一品成本
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 200-02-26
发表网址: http://www.chcj.net/redirect.php ... 185&ptid=616381

引用:

{一品成本Z----创幻论坛一品茶缘编写精品指标，大智慧主图}{飞狐通用}
{指标使用方法:
成本50是平衡,股价不上决不碰;
穿越50就启动,穿越70要拉升;
敢穿90追涨好,短线定有大行情;
回归50寻低吸,穿越上轨亮红灯。}
A50:=COST(50);
趋势:=A50*(WINNER(CLOSE)+0.3),COLORFFFFFF;
平衡:COST(50),COLORFF00FF,LINETHICK2;
启动:CROSS(C,COST(50)),COLOR99FF00,POINTDOT,LINETHICK0;
拉升:CROSS(C,COST(70)),COLORYELLOW,POINTDOT,LINETHICK0;
ZZ:=CROSS(趋势,COST(90)) AND COUNT(C<COST(90),5)>=3;
追涨:FILTER(ZZ,3),COLORFF00FF,POINTDOT,LINETHICK0;
n1:=barslast(CROSS(C,COST(50)));
n2:=barslast(CROSS(COST(50),c));
A20:if(n1<n2,A50,COST(20)),COLORFFFF00;
if(n1<n2,A50,COST(10)),COLOR99FF00;
A70:if(n1>n2,A50,COST(70)),COLORYELLOW;
if(n1>n2,A50,COST(90)),COLOR9900FF;
COST(50),COLORFF00FF,LINETHICK2;
{以下设置主图显示方式}
COST(50)*1.2,COLOR00FF00;
COST(50)*0.8,COLOR00FF00;
DRAWTEXT(启动,L,'启●动'),COLOR99FF00;
DRAWTEXT(拉升,L,'拉◆升'),COLOR00FFFF;
DRAWTEXT(追涨,L,'追★涨'),COLORFF00FF;
DRAWTEXT(CROSS(COST(90),COST(50)*1.2),L,'疯●牛'),COLOR00FFFF;
DRAWTEXT(CROSS(COST(90),COST(50)*1.2),L,'疯¤牛'),COLOR00FFFF;
DRAWICON(追涨,L,1);

引用:

公式名称: 经典震仓
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-03-01
发表网址: http://www.chcj.net/redirect.php ... 679&ptid=616381

引用:

低吸极品----{经典震仓}





牛市牛股，大幅震荡！一品继续思考。龙头股在初次强劲拉升之后,经常会出现单日大跌或者波段的凶悍震仓，如何观察、如何跟踪、如何把握？一品在{一品低吸}的基础上，再次加入均线变化、单日变化等情况，设计{经典震仓}，庄家震仓，低吸良机，现在正好用得上，故再次单独推荐！牛市极品，大家一阅!

引用:

{经典震仓----创幻论坛一品茶缘编写精品指标,大智慧副图}{飞狐通用}
{DDF:10,30,10;}
MA5:=MA(C,5);
MA10:=MA(C,10);
MA20:=MA(C,20);
MA30:=MA(C,30);
DTPL:=MA5>MA10 AND MA10>MA20 AND MA20>MA30;
DTSJ:=BARSLAST(DTPL AND NOT(REF(DTPL,1)));
ZXDT:=MA10>MA20 AND MA20>MA30 AND MA10>REF(MA10,1) AND MA20>REF(MA20,1) AND MA30>REF(MA30,1);
TDDF:=(L/REF(C,1)-1)*100<=-5 AND (REF(HHV(H,5),1)/L-1)*100>=DDF;
BMBD:=DTSJ<20 AND ZXDT AND COUNT(ZXDT,5)>=3;
特大跌幅:TDDF,COLOR00FF00,LINETHICK2;
DRZC:=COUNT(H/REF(C,1)>=1.08,7) AND C/REF(C,1)<=0.93 AND BMBD;
单日震仓:IF(DRZC>0,1,0),COLORFF00FF,LINETHICK2;
经典震仓:(DRZC OR TDDF) AND BMBD AND L=LLV(L,5),COLORYELLOW,LINETHICK2;
STICKLINE(DRZC,0,0.5,4,0),COLORYELLOW;
DRAWTEXT(DRZC OR 经典震仓,0.5,'经典◆震仓'),COLORFF00FF;

引用:

公式名称: 短线三浪
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-03-09
发表网址: http://www.chcj.net/redirect.php ... 732&ptid=616381

引用:

{一品【短线三浪Z】----创幻论坛一品茶缘编写精品指标，大智慧主图指标}{飞弧通用}
{N:1,10,5;}
MA5:MA(CLOSE,5);
MA10:MA(CLOSE,10);
MA20:MA(CLOSE,20);
MA30:MA(CLOSE,30);
MA120:MA(CLOSE,120);
MA250:MA(CLOSE,250),COLORRED;
DTPL:=MA10>MA30 AND MA20>MA30 AND  MA30>REF(MA30,1);
突破线:MIN(MA20*1.05,MA30*1.1),COLOR0066FF,POINTDOT;
差幅:=C/MIN(MA20*1.05,MA30*1.1)-1,COLOR0066FF,POINTDOT;
均线流:=(DTPL AND MA5>MA30 AND MA5<MA10)*-0.1,COLOR00FF00,POINTDOT,LINETHICK0;
偏离率:=(C<MIN(MA20*1.05,MA30*1.1) AND C>MA30)*0.1,COLORFF00FF,POINTDOT,LINETHICK0;
BDGD:=C=HHV(C,20);
GDSJ:=BARSLAST(BDGD);
REF(C,GDSJ),COLOR00FF00,POINTDOT;
{C/REF(C,GDSJ)-1,COLOR00FF00,POINTDOT;}
目标:IF(均线流=-0.1 AND 偏离率=0.1 AND GDSJ>=N,0.8,0),COLORWHITE,POINTDOT,LINETHICK0;
MBSJ:=BARSLAST(目标=0.8);
TP1:=CROSS(C,MIN(MA20*1.05,MA30*1.1)) AND REF(GDSJ,1)>=N;
TP2:=偏离率=0 AND REF(COUNT(偏离率=0.1,N)=N,1) AND C>REF(C,1);
突破:(TP1 OR TP2)*1,COLOR00FFFF,POINTDOT,LINETHICK0;
QSXS1:=MA5>REF(MA5,1);
LYHT:=DTPL AND MA5>MA10 AND NOT(QSXS1) AND REF(QSXS1,1);
MAV5:=EMA(V,5);
MAV10:=EMA(V,10);
LNMACD:=((V-MAV5)/MAV5*2+(V-MAV10)/MAV10)*10;
量坑:=LNMACD<=-10;
优选:目标 AND COUNT(量坑,3)>=1,COLORFF00FF,POINTDOT,LINETHICK0;
{以下设置主图显示方式}
{STICKLINE(均线流=-0.1,0,-0.2,5,1),color00FF00;
STICKLINE(偏离率=0.1,0,0.2,5,1),colorFF00FF;}
DRAWTEXT(目标=0.8,l,'△'),colorFFFFFF;
DRAWTEXT(突破,l,'★'),coloryellow;
{DRAWTEXT(突破,0,'突●破'),color00FFFF;}
DRAWTEXT(LYHT,(MA10+MA20)/2, '●'),COLORFF00FF;
DRAWTEXT(LYHT,(MA10+MA20)/2, '¤'),COLORFF00FF;
DRAWICON(优选,L,1);

引用:

{一品【短线三浪】----创幻论坛一品茶缘编写精品指标，大智慧副图指标}{飞弧通用}
{N:1,10,5;}
MA5:=MA(CLOSE,5);
MA10:=MA(CLOSE,10);
MA20:=MA(CLOSE,20);
MA30:=MA(CLOSE,30);
MA120:=MA(CLOSE,120);
MA250:=MA(CLOSE,250),COLORRED;
DTPL:=MA10>MA30 AND MA20>MA30 AND  MA30>REF(MA30,1);
突破线:=MIN(MA20*1.05,MA30*1.1),COLOR0066FF,POINTDOT;
差幅:C/MIN(MA20*1.05,MA30*1.1)-1,COLOR0066FF,POINTDOT;
均线流:(DTPL AND MA5>MA30 AND MA5<MA10)*-0.1,COLOR00FF00,POINTDOT,LINETHICK0;
偏离率:(C<MIN(MA20*1.05,MA30*1.1) AND C>MA30)*0.1,COLORFF00FF,POINTDOT,LINETHICK0;
BDGD:=C=HHV(C,20);
GDSJ:=BARSLAST(BDGD);
{REF(C,GDSJ),COLOR00FF00,POINTDOT;}
C/REF(C,GDSJ)-1,COLOR00FF00,POINTDOT;
目标:IF(均线流=-0.1 AND 偏离率=0.1 AND GDSJ>=N,0.8,0),COLORWHITE,LINETHICK2;
MBSJ:=BARSLAST(目标=0.8);
TP1:=CROSS(C,MIN(MA20*1.05,MA30*1.1)) AND REF(GDSJ,1)>=N;
TP2:=偏离率=0 AND REF(COUNT(偏离率=0.1,N)=N,1) AND C>REF(C,1);
突破:(TP1 OR TP2)*1,COLOR00FFFF,LINETHICK2;
MAV5:=EMA(V,5);
MAV10:=EMA(V,10);
LNMACD:=((V-MAV5)/MAV5*2+(V-MAV10)/MAV10)*10;
量坑:=LNMACD<=-10;
优选:目标 AND COUNT(量坑,3)>=1,COLORFF00FF,POINTDOT,LINETHICK0;
QSXS1:=MA5>REF(MA5,1);
LYHT:=DTPL AND MA5>MA10 AND NOT(QSXS1) AND REF(QSXS1,1);
回头:LYHT*0.5,COLOR00FF00;
{以下设置副图显示方式}
STICKLINE(均线流=-0.1,0,-0.2,5,1),color00FF00;
STICKLINE(偏离率=0.1,0,0.2,5,1),colorFF00FF;
{DRAWTEXT(目标=0.8,L,'△'),colorFFFFFF;}
DRAWTEXT(突破,1,'★'),coloryellow;
DRAWTEXT(突破,0,'突●破'),color0000FF;
DRAWICON(优选,0,1);
DRAWTEXT(回头,0.2,'●'),COLOR00FF00;
DRAWTEXT(回头,0.2,'¤'),COLOR00FF00;

引用:

公式名称: 平台突破
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-03-12
发表网址: http://www.chcj.net/redirect.php ... 963&ptid=616381

引用:

{平台突破----创幻论坛一品茶缘编写精品指标，大智慧主图指标} {飞狐通用}
{平台突破指标使用方法：
波段高低建平台，低位启动高位回；
放量拉升是突破，箱高提醒巧安排。}
{N:5,120,6;}
MA30:MA(C,30),COLOR99FF00;
BDGD:=C=HHV(C,N);
BDDD:=C=LLV(C,N);
N1:=BARSLAST(BDGD);
N2:=BARSLAST(BDDD);
高:IF(N1,REF(C,N1),REF(C,N1)),COLOR00FF00;
低:IF(N2,REF(C,N2),REF(C,N2)),COLORFFFFFF;
箱高:(高/低-1),COLOR0000FF,POINTDOT,LINETHICK0;
FLSZ:=C/REF(C,1)>=1.01 AND V>REF(V,1);
GDGD:=高>REF(高,1) AND REF(高,1)<=REF(高,2);
TP:=COUNT(GDGD,2) AND COUNT(FLSZ,2);
突破:FILTER(TP,1)*2,COLORYELLOW,POINTDOT,LINETHICK0;
启动:C>低 AND REF(C=低,1),COLOR00FF00,POINTDOT,LINETHICK0;
小心:C<高 AND REF(C=高,1),COLORFFFF88,POINTDOT,LINETHICK0;
{以下设置副图显示方式}
IF(C,C,C),COLORFF00FF;
DRAWTEXT(突破,L,'●'),COLORYELLOW;
DRAWTEXT(突破,L,'¤'),COLORYELLOW;
DRAWTEXT(启动,L,'↑'),COLOR00FF00;
DRAWTEXT(小心,H*1.01,'◎'),COLORFFFF88;

引用:

公式名称: 小箱体
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-03-15
发表网址: http://www.chcj.net/redirect.php ... 189&ptid=616381

引用:

{小箱体----创幻论坛一品茶缘编写精品指标,大智慧副图}{通用}
{小箱体指标使用说明:
短期形态小箱体,正是龙头在休息;
中线保护可买入,同时拐点更有戏!}
{N:1,10,2;P:1,3,2;}
MA10:=MA(CLOSE,10);
MA20:=MA(CLOSE,20);
MA30:=MA(CLOSE,30);
DTPL:=MA10>MA30 AND MA20>MA30 AND MA30>REF(MA30,1);
ZF:=(C/REF(C,1)-1)*100;
AA:SUM(ZF,N),COLORFFFFFF;
日期:(N+1),COLORFFFF00,POINTDOT,LINETHICK0;
{飞狐通不过：日期，保留字，不可作为变量名。
请将 日期 二字换成其他文字即可,如:字母 RQ,或者 周期.}
小箱体:ABS(AA)<=P,COLORFF00FF,POINTDOT;
成箱日:IF(BARSLAST(CROSS(小箱体,0.5))<BARSLAST(CROSS(0.5,小箱体)),BARSLAST(CROSS(小箱体,0.5))+1,0),COLORFFFFFF,POINTDOT,LINETHICK0;
买:ABS(AA)<=P AND DTPL,COLOR00FF00,POINTDOT;
↑:CROSS(AA,0),COLOR00FFFF,POINTDOT;
{以下设置副图显示方式}
STICKLINE(ABS(AA)<=P,P,-P,4,0),COLORFF00FF;
STICKLINE(ABS(AA)<=P AND DTPL,P,0,4,0),COLOR00FF00;
DRAWTEXT(↑,-P,'↑'),COLOR00FFFF;
0,COLORFFFFFF;
P,COLORFF00FF;
-P,COLORFFFF00;

引用:

公式名称: 大箱体
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-03-20
发表网址: http://www.chcj.net/redirect.php ... 092&ptid=616381

引用:

{大箱体----创幻论坛一品茶缘编写精品指标，大智慧副图指标}{飞弧通用}
{N:3,120,30;P:3,30,20;
N：表示统计周期，短期10，中期30，长期60；P：表示限制箱体高度；}
{大箱体指标使用说明:类似平台突破
阶段形成大箱体，趋势帮你判高低；
一旦突破有好戏，箱体越长越牛B!}
周期:N,COLORFFFF00,POINTDOT,LINETHICK0;
BDGD:=HHV(C,N);
BDDD:=LLV(C,N);
趋势:(C/BDDD-1)*100,COLORFFFFFF;
箱高:(BDGD-BDDD)/BDDD*100,COLOR0088FF;
大箱体:IF((BDGD-BDDD)/BDDD*100<P,P-2,p),COLOR00FF00;
启动:CROSS(趋势,0.5),COLORFFFFFF,POINTDOT,LINETHICK0;
TP:=趋势=箱高 AND REF(趋势<箱高,1);
突破:IF(FILTER(TP,N/4),箱高,P),COLORFF00FF;
牛股:FILTER(COUNT(大箱体=P-2,N/4)>=N/4-1 AND TP,N/4),COLOR0000FF,POINTDOT,LINETHICK0;
{以下设置副图显示方式}
STICKLINE(大箱体=P-2,P,P-2,4,1),COLOR00FF00;
DRAWTEXT(突破=箱高 AND 箱高>REF(箱高,1),P,'●'),COLORYELLOW;
DRAWTEXT(突破=箱高 AND 箱高>REF(箱高,1),P,'¤'),COLORYELLOW;
DRAWTEXT(启动,5,'↑'),COLOR00FF00;
DRAWICON(牛股,P,1);

引用:

公式名称: 斜面推高
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-03-27
发表网址: http://www.chcj.net/redirect.php ... 937&ptid=616381

引用:

拉升在即--【斜面推高】主副图
（附注：2007年以来，斜面推高-推高信号20天10%成功率达到95%以上，其他数字有兴趣的朋友可以自己测试。）

引用:

{一品【斜面推高Z】----创幻论坛一品茶缘编写精品指标，大智慧主图指标}{飞弧通用}
{参数:N:1,20,10;P:1,8,4;}
{斜面推高指标使用说明：
均线多头向上行，斜面出现好行情；
连续小幅在推高，及时买入享拉升！}
MA5:MA(C,5);
MA10:MA(C,10);
MA20:MA(C,20);
MA30:MA(C,30);
DTPL:=MA10>MA20 AND MA20>MA30 AND MA20>REF(MA20,1) AND MA30>REF(MA30,1);
DTSJ:=BARSLAST(CROSS(DTPL,0.1));
斜面:DTSJ*DTPL>0,COLOR00FFFF,POINTDOT,LINETHICK0;
ZF:=(C/REF(C,1)-1)*100;
WBTG:=COUNT(C>MA10 AND MA10>REF(MA10,1),3)=3;
LXXZ:=COUNT(ABS(ZF)<P,N)>=N-2;
推高:(LXXZ AND WBTG AND 斜面 AND COUNT(ZF>5,3)=0)*1,COLOR00FF00,POINTDOT,LINETHICK0;
BCXM:=COUNT(斜面,5)=5;
SL:=V<REF(V,1);
缩量:((COUNT(SL,5)>=3 OR COUNT(SL,6)>=4) AND SL AND V<MA(V,5))*1,COLORFFFFFF,POINTDOT,LINETHICK2;
优选:推高 AND BCXM AND 缩量,COLORFF00FF,POINTDOT,LINETHICK2;
{以下设置主图显示方式}
STICKLINE(斜面,MA20,(MA20+MA30)/2,4,0),COLOR00FFFF;
STICKLINE(斜面,MA30,(MA20+MA30)/2,4,0),COLORFF00FF;
STICKLINE(斜面 AND 缩量,(MA20+MA30)/2*1.005,(MA20+MA30)/2*0.995,4,1),COLORFFFFFF;
DRAWTEXT(推高,l,'△'),COLOR00FF00;
DRAWICON(优选,L,1);

引用:

{一品【斜面推高】----创幻论坛一品茶缘编写精品指标，大智慧主图指标}{飞弧通用}
{参数:N:1,20,10;P:1,8,4;}
{斜面推高指标使用说明：
均线多头向上行，斜面出现好行情；
连续小幅在推高，及时买入享拉升！}
MA5:=MA(C,5);
MA10:=MA(C,10);
MA20:=MA(C,20);
MA30:=MA(C,30);
DTPL:=MA10>MA20 AND MA20>MA30 AND MA20>REF(MA20,1) AND MA30>REF(MA30,1);
DTSJ:=BARSLAST(CROSS(DTPL,0.1));
斜面:DTSJ*DTPL,COLOR00FFFF,POINTDOT,LINETHICK2;
ZF:=(C/REF(C,1)-1)*100;
WBTG:=COUNT(C>MA10 AND MA10>REF(MA10,1),3)=3;
LXXZ:=COUNT(ABS(ZF)<P,N)>=N-2;
推高:(LXXZ AND WBTG AND 斜面 AND COUNT(ZF>5,3)=0)*DTSJ,COLOR00FF00,LINETHICK1;
BCXM:=COUNT(斜面,5)=5;
SL:=V<REF(V,1);
缩量:((COUNT(SL,5)>=3 OR COUNT(SL,6)>=4) AND SL AND V<MA(V,5))*1,COLORFFFFFF,POINTDOT,LINETHICK2;
优选:推高 AND BCXM AND 缩量,COLORFF00FF,POINTDOT,LINETHICK2;
{以下设置副图显示方式}
STICKLINE(斜面,斜面*1.001,斜面*0.999,4,1),color00FFFF;
STICKLINE(缩量,0,1,4,1),COLORFFFFFF;
STICKLINE(缩量,0,-1,4,1),COLOR00FF00;
DRAWICON(优选,5,1);

引用:

公式名称: 35秘密Z
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-04-03
发表网址: http://www.chcj.net/redirect.php ... 321&ptid=616381

引用:

{35秘密Z----创幻论坛一品茶缘编写,大智慧主图}{通用}
MA3:MA(C,3),COLOR00FF00;
MA5:MA(C,5),COLORFFFFFF;
ZX:=(MA3+MA5)/2;
MA20:MA(C,20),COLORFF00FF;
MA30:MA(C,30),COLORYELLOW;
QSXS:=MA5>=MA30 AND MA30>REF(MA30,1);
GD:=ZX>=REF(ZX,1) AND REF(ZX,1)<REF(ZX,2);
YB:=C>REF((O-C)/2+C,2);
买:CROSS(C,ZX) AND (GD OR YB) AND QSXS,COLOR00FF00,POINTDOT,LINETHICK0;
优:买 AND MA5>REF(MA5,1),COLORYELLOW,POINTDOT,linethick0;
{以下设置主图显示方式}
STICKLINE(买,h,l,0,1),COLOR00FF00,linethick2;
STICKLINE(买,o,c,4,1),COLOR00FF00,linethick2;
STICKLINE(优,h,l,0,1),COLORYELLOW,linethick2;
STICKLINE(优,o,c,4,1),COLORYELLOW,linethick2;
DRAWTEXT(买,L*0.99, '买'),COLOR00FF00;
DRAWICON(优,L,1);

引用:

公式名称: 一品MACD
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-04-09
发表网址: http://www.chcj.net/redirect.php ... 326&ptid=616381

引用:

双核心,更分明----一品ＭＡＣＤ


{一品MACD----创幻论坛一品茶缘编写，大智慧副图}{飞狐通用}
{N:1,20,10;参数N表示洗盘前拉升时间不超过N天；}
{一品MACD指标使用方法：
ＭＡＣＤ巧变形，趋势判断更分明；
启动初涨拉升快，洗盘低买高位清。}
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:200*(DIFF-DEA),COLORSTICK;
趋势:2*(MACD-REF(MACD,1)),COLORFFFFFF,LINETHICK2;
启动:IF(CROSS(趋势,0) AND MACD<0,10,0),COLOR00FF00;
拉升:IF(CROSS(MACD,0),10,0),COLOR00FFFF;
SZSJ:=BARSLAST(CROSS(趋势,0))+1;
LSSJ:=BARSLAST(CROSS(MACD,0))+1;
洗盘:IF(趋势<0 AND SZSJ<N AND LSSJ<N,-10,0),COLORFF00FF;
推高:IF(CROSS(趋势,0) AND MACD>0,10,0),COLOR0000FF;
小心:IF(CROSS(0,趋势) AND (SZSJ>=N OR LSSJ>=N) AND MACD>0,-10,0),COLORFFFF00;
{以下设置副图显示方式}
STICKLINE(趋势>0,趋势,0,2,0),COLOR00FFFF;
STICKLINE(趋势<0,趋势,0,2,0),COLOR008800;
STICKLINE(洗盘<0 AND C<REF(C,1),洗盘,0,2,1),COLORFF00FF;
STICKLINE(小心<0,趋势,0,2,0),COLORFFFF00;
DRAWTEXT(拉升,0,'△'),COLOR00FFFF;
DRAWTEXT(推高,0,'★'),COLOR0000FF;
DRAWTEXT(REF(CROSS(MACD,0),1),MACD*2,'高卖？'),COLORFF00FF;
DRAWTEXT(REF(CROSS(0,MACD),1),MACD,'低买？'),COLORFFFFFF;

引用:

公式名称: 简单KDJ
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-04-13
发表网址: http://www.chcj.net/redirect.php ... 476&ptid=616381

引用:

重读经典----简单KDJ


{简单KDJ----创幻论坛一品茶缘编写,通用副图指标}
{该指标优化基础思路来自股往金未来先生,特此致谢.}
{简单KDJ指标使用方法：
重读经典ＫＤＪ，Ｊ值转向定策略；
超跌关注重启买，加码小心更明确！}
RSV:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100;
K:SMA(RSV,3,1),COLORFFFFFF;
D:SMA(K,3,1),COLOR00FFFF;
J:3*K-2*D,COLORFF00FF;
超跌:IF(J<0,10,0),COLORFFFF00;
BDDD:=LLV(J,2)=LLV(J,8);
重启:IF(CROSS(J,REF(J+0.01,1)) AND BDDD AND J<20,30,0),COLOR00FF00;
加码:IF(CROSS(J,REF(J+0.01,1)) AND BDDD AND BETWEEN(J,20,60),1,0),COLOR00FFFF,POINTDOT,LINETHICK0;
BDGD:=HHV(J,2)=HHV(J,8) AND J>80;
小心:IF(CROSS(REF(J-0.01,1),J) AND REF(BDGD,1),70,100),COLOR0000FF;
DRAWTEXT(加码,J,'△'),COLOR00FFFF;

引用:

公式名称: 建仓拉升
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-04-17
发表网址: http://www.chcj.net/redirect.php ... 291&ptid=616381

引用:

成本均线----建仓拉升


{建仓拉升----创幻论坛一品茶缘编写,大智慧主图指标}
{建仓拉升指标使用方法：
成本均线ＣＹＣ，空头排列建仓期；
空转多头建仓毕，短线拐点拉升急！}

CYC5:CYC(5);
CYC13:CYC(13);
CYC34:CYC(34);
CYC0:MAXCYC,COLORFF9900;
DTPL:=CYC5>CYC13 AND CYC13>CYC34 AND CYC34>CYC0;
建仓:CROSS(DTPL,0.9),COLOR00FFFF,POINTDOT,LINETHICK0;
LS1:=CROSS(CYC5,REF(CYC5+0.01,1));
LS2:=CROSS(C,CYC5) AND (C=HHV(C,4) OR C>REF(C,4));
拉升:FILTER(LS1 OR LS2,3) AND COUNT(DTPL,5)>=4,COLORFF00FF,POINTDOT,LINETHICK0;
{以下设置主图显示方式}
DRAWTEXT(建仓,CYC0,'★建仓完毕'),COLOR00FFFF;
DRAWICON(拉升,CYC34,1);
DRAWTEXT(拉升,CYC13,'↑'),COLORFFFFFF;

一品注：飞狐无CYC函数，本指标请用本帖1792楼原码代替。数字、信号略有差异。
通达信同样参考飞狐替代版，并请分别在建仓://拉升:的冒号：后面加上等号=，避免主图压缩现象。

引用:

{建仓拉升----创幻论坛一品茶缘编写主图指标,飞狐替代版}
{建仓拉升指标使用方法：
成本均线ＣＹＣ，空头排列建仓期；
空转多头建仓毕，短线拐点拉升急！}
Var2:=(3*HIGH+LOW+OPEN+2*CLOSE)/7;
Var5:=AMOUNT/SUM(AMOUNT,5);
Var13:=AMOUNT/SUM(AMOUNT,13);
Var34:=AMOUNT/SUM(AMOUNT,34);
Var0:=AMOUNT/SUM(AMOUNT,55);
CYC5:DMA(Var2,Var5);
CYC13:DMA(Var2,Var13);
CYC34:DMA(Var2,Var34);
CYC0:DMA(Var2,Var0),COLORFF9900;
DTPL:=CYC5>CYC13 AND CYC13>CYC34 AND CYC34>CYC0;
建仓:CROSS(DTPL,0.9),COLOR00FFFF,POINTDOT,LINETHICK0;
LS1:=CROSS(CYC5,REF(CYC5+0.01,1));
LS2:=CROSS(C,CYC5) AND (C=HHV(C,4) OR C>REF(C,4));
拉升:FILTER(LS1 OR LS2,3) AND COUNT(DTPL,5)>=4,COLORFF00FF,POINTDOT,LINETHICK0;
{以下设置主图显示方式}
DRAWTEXT(建仓,CYC0,'★建仓完毕'),COLOR00FFFF;
DRAWICON(拉升,CYC34,1);
DRAWTEXT(拉升,CYC13,'↑'),COLORFFFFFF;

引用:

公式名称: 阶段统计
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-04-20
发表网址: http://www.chcj.net/redirect.php ... 652&ptid=616381

引用:

选龙助手----阶段统计


{阶段统计----创幻论坛一品茶缘编写，副图指标} {通用}
{N1:1900,2500,2007;Y1:1,12,1;R1:1,31,8;----本行参数表示统计开始的年月日；}
{N2:1900,2500,2007;Y2:1,12,3;R2:1,31,30;----本行参数表示统计结束的年月日；}
{DDF:10,30,18;----表示阶段高点回落的跌幅;一般股票牛市可以只选择10，18为超跌安全买点；}
{阶段统计指标使用说明：
参数调整变周期，阶段统计比高低；
同期对比选龙头，黄坑提示可低吸。}
年:=YEAR;
月:=MONTH;
日:=DAY;
始:=年=N1 AND 月=Y1 AND 日=R1;
终:=年=N2 AND 月=Y2 AND 日=R2;
期:BARSLAST(始),COLORFFFFFF;
停:=BARSLAST(终);
涨: (C/REF(C,期)-1)*100,COLOR00FFFF;
高: (HHV(H,期)/REF(C,期)-1)*100*(期>=1),COLORFF00FF;
HLSJ:=BARSLAST(CROSS(高=REF(高,1),0.5))+1;
HJK:=(REF(H,HLSJ)/L-1)*100-DDF;
坑: (HJK>0)*HJK,COLOR00FFFF;
{以下设置副图显示方式}
STICKLINE(始,0,50,1,0),COLOR00FF00;
STICKLINE(终,0,50,1,0),COLORFF00FF;
DRAWTEXT(始,80,'开始'),COLOR00FF00;
DRAWTEXT(终,80,'结束'),COLORFF00FF;
STICKLINE(坑,涨,高-DDF,4,0),COLOR00FFFF;
0,COLORFFFFFF;

引用:

关于阶段统计与选股：
1、该指标只是对于目标股进行一个阶段的涨幅进行简单的统计（飞弧软件有此功能），并非属于买卖点的选择与确定的指标，没有必要做成选股公式；
2、因为时间段是灵活的，所以该指标同样无法编写固定的选股公式，就是无法适用于自动预警（也没有必要），还请大家在使用时根据自己的需要调整开始与结束的周期参数，然后再选股，同样很快的啊。

具体选股方法如下：
（1）首先确定你要统计的时间段，调整开始、结束的参数周期；
（2）开始选股：
A、统计时间确定为该时段结束的日子；
B、条件选择：高----大于----50（就是你选择的目标在本阶段内的最大涨幅达到+50%以上，一般就是龙头）；
C、选股到指定板块----确定；这样就可以选出你需要的目标股了。

3、选择出龙头目标股后的作用：
（1）一品觉得这样的阶段特大涨幅龙头目标股，在适当休息后，一般都有再次爆发的可能，所以值得连续跟踪；然后利用其他能够确定买卖点的指标来确定自己的操作；
（2）可以确定某个板块中的龙头目标，然后思考与她关联密切的目标股，对比涨幅，看能否有补涨机会；
例如：一品的股市三人行中的000562、000563与600030//600266、600263与600386//600651、600654与000532……基本都有这样的参考与对比的价值。
（3）龙头可能涨得更快，走在前面；而龙头休息的时候，与她关联密切的、同一板块的个股，可能就要补涨；这就是问题的答案。所以我们要注意的就是把握好龙头的领涨与非龙头的补涨之间的节奏问题了。最近的航天军工概念的600765（龙头）与002013（非龙头）、600038（非龙头），就有这样的明显关联。

以上思路，仅供大家参考。一品真诚欢迎大家的批评与交流！

引用:

公式名称: 简单F10
适用软件: 大智慧L2
发 表 人: 一品茶缘     
发表日期: 2007-04-24
发表网址: http://www.chcj.net/redirect.php ... 494&ptid=616381

引用:

小参考----简单F10


{简单F10----创幻论坛一品茶缘收集整理，大智慧新一代副图指标}
{感谢祥云版主\wjff等朋友提供部分原码与帮助!}
AA:=DISPSTATUS=2;
买入:STRFIND(Extrastring('评级'),'买入',1)>0,COLOR00FF00;
增持:STRFIND(Extrastring('评级'),'增持',1)>0,COLOR0000FF;
持有:STRFIND(Extrastring('评级'),'持有',1)>0,COLORFF00FF;
STICKLINE(C*AA,0,8,8,1),COLORFFFFFF;
STICKLINE(买入*AA,0,8,8,0),COLOR00FF00;
STICKLINE(增持*AA,0,8,8,0),COLOR0000FF;
STICKLINE(持有*AA,0,8,8,0),COLORFF00FF;
10,COLOR0000FF;
{以下设置简单F10信息}
DRAWTEXTREL(10,50,''+STKLABEL+' '+STKNAME),LINETHICK1,Colorgreen;
DRAWTEXTREL(400,50,'机构评级:'+Extrastring('评级')),colorffffff;
DD:=FINANCE2(1);SS:=FINANCE2(7);FF:=FINANCE2(18);GG:=FINANCE2(33);HH:=DYNAINFO(39);
DRAWTEXTREL(10,250,'总股本:'+NUMTOSTRN(DD,0)+'万' +' 流通A股:'+NUMTOSTRN(SS,0)+'万'),COLOR00ffff;
DRAWTEXTREL(400,250,'市盈率:'+NUMTOSTRN(HH,2)+'%'+' 每股收益:'+NUMTOSTRN(GG,3)),COLORffffff;
MM:=FINANCE2(34);NN:=FINANCE2(18);PP:=FINANCE2(32);QQ:=FINANCE2(37);
DRAWTEXTREL(10,450,'净资产:'+NUMTOSTRN(MM,2)+'元'+' 净资收益率:'+NUMTOSTRN(QQ,2)+'%'),COLORRED;
DRAWTEXTREL(400,450,'公积金:'+NUMTOSTRN(NN,2)+'元'+' 未分配利润:'+NUMTOSTRN(PP,2)+'元'),COLORRED;
DRAWTEXTREL(10,650,'所属板块:'+BKNAME),COLORFF00FF;
{//个股F10信息设置结束！};


一品注:通达信\传统大智慧无法编写,抱歉.

引用:

公式名称: 一品倍增Z
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-04-26
发表网址: http://www.chcj.net/redirect.php ... 422&ptid=616381

引用:

一书一指标----一品倍增Z


{一品倍增Z----创幻论坛一品茶缘编写精品指标，通用主图}
{一品注：该指标思路来源于黄家坚先生《股市倍增术》一书，一本书一个指标全部体现！}
{指标使用方法：
一品倍增有诀窍，年线上拐好股票；
股价突破加上拐，中线买点就一招。
买点前期找低点，低点翻番作目标；
涨幅八十先预警，能够翻番乐逍遥！
蜻蜓点水好低吸，四渡赤水牛难找；
鱼跃龙门再翻番，神龙飞天上九霄！}
P1:=5;P2:=10;P3:=20;P4:=30;
MA250:EMA(C,250),COLOR0000FF,LINETHICK2;
GD250:=MA250>=REF(MA250,1) AND REF(MA250,1)<REF(MA250,2);
XS250:=MA250>REF(MA250,1);
TP250:=CROSS(C,MA250);
HC250:=COUNT(C>MA250,10)>=8 AND (CROSS(L,MA250*1.02) OR CROSS(L,MA250));
YXTP:=FILTER(COUNT(TP250,3) AND COUNT(C>MA250,3)=3,5);
YXHC:=FILTER(COUNT(HC250,3) AND COUNT(C<MA250,3)=3,5);
HCBP:=FILTER(COUNT(HC250,3) AND C>MA250,5);
JDDD:=L=LLV(L,30) AND COUNT(L<MA250,5)=5;
DDSJ:=BARSLAST(JDDD);
MD1:=YXTP AND XS250;
MD2:=COUNT(C>MA250,3)=3 AND GD250;
买点:FILTER(MD1 OR MD2,5),COLORFF00FF,POINTDOT,LINETHICK0;
MDSJ:=BARSLAST(买点);
低点:REF(L,DDSJ)*(MDSJ<DDSJ),COLOR00FF00,POINTDOT,LINETHICK0;
IF(DDSJ>0,DDSJ,DDSJ)*(MDSJ<DDSJ),COLORFFFFFF,POINTDOT,LINETHICK0;
目标:低点*2,COLORFF00FF,POINTDOT,LINETHICK0;
涨:(C/低点-1),COLOR0000FF,POINTDOT,LINETHICK0;
警:低点*1.8,COLOR00FFFF,POINTDOT,LINETHICK0;
四渡赤水:=COUNT(YXTP OR YXHC,120)>=4 AND YXTP;
达标:=FILTER(CROSS(H,目标) AND NOT(低点=0),10);
DBSJ:=BARSLAST(达标);
BDXG:=H=HHV(H,30) AND DBSJ<3;
XGSJ:=BARSLAST(BDXG);
REF(H,XGSJ),COLOR00FF00,POINTDOT;
鱼跃龙门:CROSS(C,REF(H+0.001,XGSJ)),COLORFF00FF,POINTDOT,LINETHICK0;

{以下设置主图显示方式}
MA1:MA(C,P1),COLOR00FFFF;
MA2:MA(C,P2),COLORFF00FF;
MA3:MA(C,P3),COLOR00FF00;
MA4:MA(C,P4),COLORFFFFFF;
DRAWTEXT(GD250,MA250 , '拐△点'),COLORFFFFFF;
DRAWTEXT(YXTP,L*0.96 , '突●破'),COLOR00FFFF;
DRAWTEXT(买点,L*0.99 , '买★点'),COLORFF00FF;
DRAWTEXT(HCBP,L*0.98 , '蜻蜓◆点水'),COLOR00FF00;
DRAWTEXT(四渡赤水,L*0.92 , '四渡●赤水'),COLORFFFFFF;
DRAWTEXT(四渡赤水,L*0.92 , '四渡¤赤水'),COLORFFFFFF;
DRAWICON(买点,L*0.99,1);
DRAWTEXT(达标,H*1.02 , '达●标'),COLOR00FFFF;
DRAWTEXT(鱼跃龙门,L*0.99 , '鱼跃★龙门'),COLORFF00FF;
DRAWICON(鱼跃龙门,L*0.99,1);

引用:

【一品倍增Z】主图信息补充,大智慧新一代可用,方便查阅.请将以下原码直接放到【一品倍增Z】后面即可.(【一品倍增Z】请在本帖2045楼/69页查阅)


{以下设置一品倍增Z价位定位信息----大智慧L2可用}
DRAWTEXTREL(10,50,''+STKLABEL+' '+STKNAME),LINETHICK1,Colorgreen;
DRAWTEXTREL(10,100,'最新价位:'+NUMTOSTRN(C,2)+'元'),colorff00ff;
DRAWTEXTREL(10,150,'前期低点:'+NUMTOSTRN(低点,2)+'元'),colorffffff;
DRAWTEXTREL(10,200,'目标价位:'+NUMTOSTRN(目标,2)+'元'+'（+100%）'),colorffffff;
DRAWTEXTREL(10,250,'二翻价位:'+NUMTOSTRN(目标*2,2)+'元'+'（+300%）'),colorffffff;
DRAWTEXTREL(10,300,'三翻价位:'+NUMTOSTRN(目标*4,2)+'元'+'（+700%）'),colorffffff;
DRAWTEXTREL(10,350,'低点上涨:'+NUMTOSTRN(涨*100,2)+'%'),color0000ff;
{//价位定位信息设置结束！};

引用:

一品注:指标文字较多,是为了便于初次观察理解,熟悉后建议修改如下:
'拐△点'----△
'突●破'----●
'买★点'----买
'蜻蜓◆点水'----◆
'四渡●赤水'----●
'四渡¤赤水'----¤
'达●标'----达●标
'鱼跃★龙门'----★

[ 本帖最后由 蓝鼠 于 2008-3-27 08:09 编辑 ]

引用:

公式名称: KD追涨
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-05-04
发表网址: http://www.chcj.net/redirect.php ... 855&ptid=616381

引用:

{KD追涨----创幻论坛一品茶缘编写，大智慧副图}{通用}
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=(SMA(RSV,3,1));
D:=(SMA(K,3,1));
KK:=INTPART(SMA(RSV,3,1));
DD:=INTPART(SMA(K,3,1));
N:KK+DD,COLORff00ff,LINETHICK2;
SZ:=(C/REF(C,1)-1)*100>=2;
QSXS:=N>REF(N,1) AND BETWEEN(N,100,150);
ZZ:=QSXS AND SZ;
追涨:IF(FILTER(ZZ,3),120,50),COLORYELLOW;
GWGD2:=N<REF(N,1) AND REF(N,1)>=160 AND REF(N,1)>=REF(N,2);
风险:IF(GWGD2,95,160),COLOR00ff00;
{以下设置副图显示方式}
100,COLORWHITE,POINTDOT;
STICKLINE(C,100,100,4,0),COLORWHITE;

引用:

公式名称: 五线布林Z
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-05-05
发表网址: http://www.chcj.net/redirect.php ... 363&ptid=616381

引用:

五一好礼----五线布林Z


{五线布林Z----一品茶缘编写精品指标，大智慧主图}{通用}
{N:1,10,5;参数N表示步林口上下轨之间的最小差距;}
{五线布林Z指标使用方法：
一品五线变布林，开合趋势真分明；
突破上轨拉升快，回归中轨反弹轻。}
N1:=10;P1:=3;
BBI:=(MA(CLOSE,3)+MA(CLOSE,6)+MA(CLOSE,12)+MA(CLOSE,24))/4;
上:BBI+P1*STD(BBI,N1),COLORYELLOW;
险:IF(BBI*1.15>上*1.03,上*1.06,上*1.03),COLOR0000FF,POINTDOT,LINETHICK0;
下:BBI-P1*STD(BBI,N1),COLORFF00FF;
中:BBI,COLORWHITE;
AA:BBI+P1*STD(BBI,N1)/2,COLOR88FF88;
BB:BBI-P1*STD(BBI,N1)/2,COLOR88FF88;
MA30:MA(C,30),POINTDOT,COLOR00FF00;
QSXS1:=AA>REF(AA,1) AND BBI>REF(BBI,1);
QSXS2:=COUNT(MA30>REF(MA30,1),5)=5;
FLSZ:=C>O AND V>REF(V,1);
RMG:=FLSZ AND (C/REF(C,1)-1)*100>=2;
SCAA:=CROSS(C,AA) OR (O<AA AND C>AA);
BLK:=LLV((上-下),2)=LLV((上-下),10);
XBLK:=(上/下-1)*100<=N;
BLKSJ:=BARSLAST(BLK)+1;
拉升:FILTER(SCAA AND FLSZ AND (QSXS1 OR (QSXS2 AND BLKSJ<5)),3),COLORFF00FF,POINTDOT,LINETHICK0;
优选:拉升 AND COUNT(XBLK,4)>=1 AND RMG,COLOR00FF00,POINTDOT,LINETHICK0;
XZF:=(C/REF(C,1)-1)*100<=1;
XPL:=ABS(C-BBI)/BBI*100<=2 OR ABS(l-BBI)/BBI*100<=2;
回:COUNT(QSXS1,8)>=6 AND XZF AND XPL,COLORFFFFFF,POINTDOT,LINETHICK0;
{以下设置主图显示方式}
STICKLINE(拉升,(O+C)/2,(O+C)/2,4,0),COLORFF00FF;
STICKLINE(拉升,H,L,0,1),COLORFF00FF;
DRAWTEXT(拉升,L*0.99,'◆'),COLORFF00FF;
DRAWTEXT(回,L*0.99,'回'),COLORFFFFFF;
DRAWTEXT(XBLK,BBI*1.01,'口'),COLOR00FF00;
STICKLINE(优选,H,L,1,0),COLORFF00FF;
DRAWICON(优选,L*0.99,1);
高:=((H/BBI-1)*100>=15 AND (H/上-1)*100>=3) OR (H/上-1)*100>=6;
STICKLINE(高,H*1.01,H*1.02,4,0),COLOR00FFFF;

引用:

应各位朋友要求,提供一品指标五线布林Z(通达信版本)


{五线布林Z----一品茶缘编写精品指标，大智慧主图}{通用}
{N:1,10,5;参数N表示步林口上下轨之间的最小差距;}
{五线布林Z指标使用方法：
一品五线变布林，开合趋势真分明；
突破上轨拉升快，回归中轨反弹轻。}
N1:=10;P1:=3;
BBI:=(MA(CLOSE,3)+MA(CLOSE,6)+MA(CLOSE,12)+MA(CLOSE,24))/4;
上:BBI+P1*STD(BBI,N1),COLORYELLOW;
险:IF(BBI*1.15>上*1.03,上*1.06,上*1.03),COLOR0000FF,POINTDOT;
下:BBI-P1*STD(BBI,N1),COLORFF00FF;
中:BBI,COLORWHITE;
AA:BBI+P1*STD(BBI,N1)/2,COLOR88FF88;
BB:BBI-P1*STD(BBI,N1)/2,COLOR88FF88;
MA30:MA(C,30),POINTDOT,COLOR00FF00;
QSXS1:=AA>REF(AA,1) AND BBI>REF(BBI,1);
QSXS2:=COUNT(MA30>REF(MA30,1),5)=5;
FLSZ:=C>O AND V>REF(V,1);
RMG:=FLSZ AND (C/REF(C,1)-1)*100>=2;
SCAA:=CROSS(C,AA) OR (O<AA AND C>AA);
BLK:=LLV((上-下),2)=LLV((上-下),10);
XBLK:=(上/下-1)*100<=N;
BLKSJ:=BARSLAST(BLK)+1;
拉升:=FILTER(SCAA AND FLSZ AND (QSXS1 OR (QSXS2 AND BLKSJ<5)),3),COLORFF00FF,POINTDOT,LINETHICK0;
优选:=拉升 AND COUNT(XBLK,4)>=1 AND RMG,COLOR00FF00,POINTDOT,LINETHICK0;
XZF:=(C/REF(C,1)-1)*100<=1;
XPL:=ABS(C-BBI)/BBI*100<=2 OR ABS(L-BBI)/BBI*100<=2;
回:=COUNT(QSXS1,8)>=6 AND XZF AND XPL,COLORFFFFFF,POINTDOT,LINETHICK0;
{以下设置主图显示方式}
STICKLINE(拉升,(O+C)/2,(O+C)/2,4,0),COLORFF00FF;
STICKLINE(拉升,H,L,0,1),COLORFF00FF;
DRAWTEXT(拉升,L*0.99,'◆'),COLORFF00FF;
DRAWTEXT(回,L*0.99,'回'),COLORFFFFFF;
DRAWTEXT(XBLK,BBI*1.01,'口'),COLOR00FF00;
STICKLINE(优选,H,L,1,0),COLORFF00FF;
DRAWICON(优选,L*0.99,1);
高:=((H/BBI-1)*100>=15 AND (H/上-1)*100>=3) OR (H/上-1)*100>=6;
STICKLINE(高,H*1.01,H*1.02,4,0),COLOR00FFFF;
DRAWICON(高,H*1.05,12);

引用:

公式名称: MA20斜率
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-05-11
发表网址: http://www.chcj.net/redirect.php ... 724&ptid=616381

引用:

{MA20斜率----创幻论坛一品茶缘编写，通用副图}
{MA20斜率指标使用方法：
均线斜率判股池，正值上涨好趋势；
拉升走强超涨险，短线超跌可低吃！}
AA:=EMA(C,20);
斜率:(AA/REF(AA,1)-1)*1000,COLORFF00FF;
拉升:IF(CROSS(斜率,10),10,0),COLOR00FFFF;
超涨:IF(斜率-REF(llV(斜率,3),1)>=18,20,0),COLOR0000FF;
超跌:IF(REF(HHV(斜率,3),1)-斜率>=18,-10,0),COLOR00FF00;
20,POINTDOT,COLOR0000FF;
10,POINTDOT,COLORFFFFFF;
-10,POINTDOT,COLORFFFFFF;

引用:

公式名称: 一品主力
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-05-20
发表网址: http://www.chcj.net/redirect.php ... 573&ptid=616381

引用:

经典解读----一品主力


{一品主力----创幻论坛一品茶缘优化经典指标系列----主力买卖，通用副图指标}
{一品主力指标使用说明：
主力买卖经典读，短中上拐可买入；
多头初现应优选，高位下拐请卖出。}
N1:=6;N2:=12;N3:=26;
MTM:=C-REF(C,1);
DX:100*EMA(EMA(MTM,N1),N1)/EMA(EMA(ABS(MTM),N1),N1),COLOR00FF00;
ZX:100*EMA(EMA(MTM,N2),N2)/EMA(EMA(ABS(MTM),N2),N2),COLOR00FFFF;
CX:100*EMA(EMA(MTM,N3),N3)/EMA(EMA(ABS(MTM),N3),N3),COLORFF00FF;
DXGD:=LLV(DX,2)=LLV(DX,5) AND CROSS(DX,MA(DX,2));
ZXGD:=LLV(ZX,2)=LLV(ZX,5) AND CROSS(ZX,MA(ZX,2)) AND DX>ZX;
短买:IF(DXGD AND BETWEEN(DX,0,60) AND ZX>0,1,0),COLORFFFFFF,POINTDOT,LINETHICK0;
中买:IF(ZXGD AND BETWEEN(DX,0,50) AND BETWEEN(CX,0,50),2,0),COLOR00FFFF,POINTDOT,LINETHICK0;
DTPL:=DX>ZX AND ZX>CX AND CX>0;
QSXS:=DX>REF(DX,1) AND ZX>REF(ZX,1);
TSJC:=CROSS(DX,CX) AND CROSS(ZX,CX);
优选:IF(CROSS(DTPL,0.8) AND (TSJC OR COUNT(QSXS,3)=3) AND CX<40,1,0),COLOR0000FF,POINTDOT,LINETHICK0;
↑:IF(LLV(DX,2)=LLV(DX,7) AND COUNT(DX<0,2) AND CROSS(DX,MA(DX,2)),1,-50),COLOR00FF00;
↓:IF(HHV(DX,2)=HHV(DX,7) AND COUNT(DX>50,2) AND CROSS(MA(DX,2),DX),50,80),COLOR0000FF;
短卖:=IF(CROSS(ZX,DX),1,0);
中卖:=IF(CROSS(CX,ZX) AND DX<ZX,2,0);
{以下设置副图显示方式}
STICKLINE(DX>0,0,DX,4,0),COLOR00FF00;
STICKLINE(ZX>0,0,ZX,4,0),COLOR00FFFF;
STICKLINE(CX>0,0,CX,4,0),COLORFF00FF;
0,COLORFFFFFF;
DRAWTEXT(短买,0,'△'),COLORFFFFFF;
DRAWTEXT(中买,0,'★'),COLOR00FFFF;
DRAWTEXT(短卖,0,'↓'),COLORFFFF00;
DRAWTEXT(中卖,0,'□'),COLORFF6600;
DRAWICON(优选,0,1);
{以下设置指标使用提示,明白以后可以删除.}
BDDW:=FILTER(DX<20 AND ZX<20,60);
DRAWTEXT(BDDW,80,'主力经典读'),COLORFFFFFF;
DRAWTEXT(BDDW,60,'上拐可买入'),COLORFFFFFF;
DRAWTEXT(REF(BDDW,15),80,'多头应优选'),COLOR00FFFF;
DRAWTEXT(REF(BDDW,15),60,'下拐请卖出'),COLOR00FFFF;

引用:

公式名称: 放量攻击
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-05-22
发表网址: http://www.chcj.net/redirect.php ... 253&ptid=616381

引用:

量能跟踪----放量攻击


{放量攻击----创幻论坛一品茶缘编写，通用副图指标}
{N:5,60,34;}
{放量攻击指标使用说明：
量能饱和看股市，放量上涨要升值；
攻击凶猛防登顶，缩量小坑幸福池。}
A:=EMA(AMOUNT/C/1000000,7);
MID :=EMA(A,N);
UPPER:=MID + 2*STD(A,N);
LOWER:=MID - 2*STD(A,N);
量能:(A-LOWER)/(UPPER-LOWER)*100,COLORFFFFFF;
放量:IF(CROSS(量能,70),70,50),COLOR00FF00;
↑:IF(CROSS(量能,50),1,0),COLORFF00FF;
攻击:IF(CROSS(量能,100),1,0),COLOR0000FF,POINTDOT,LINETHICK0;
缩量:IF(CROSS(30,量能),1,0),COLORFFFF00,POINTDOT,LINETHICK0;
{以下设置副图显示方式}
100,POINTDOT,COLORFF00FF;
70,COLORFFFFFF;
30,POINTDOT,COLORFFFFFF;
0,POINTDOT,COLORFF6600;
STICKLINE(量能>70,70,量能,4,0),COLOR00FFFF;
STICKLINE(量能>100,100,量能,4,0),COLOR0000FF;
STICKLINE(量能<30,30,量能,4,0),COLORFFFF00;
STICKLINE(量能<0,0,量能,4,0),COLOR00FF00;
DRAWTEXT(↑,50,'↑'),COLORFF00FF;
DRAWTEXT(攻击,70, '↑'),COLOR0000FF;
DRAWTEXT(缩量,30, '↓'),COLORFFFF00;
{以下设置指标使用提示,明白以后可以删除.}
BDDW:=FILTER(缩量,60);
DRAWTEXT(BDDW,45,'量能看股市'),COLORFFFFFF;
DRAWTEXT(BDDW,25,'放量要升值'),COLORFFFFFF;
DRAWTEXT(REF(BDDW,15),45,'攻击防登顶'),COLOR00FFFF;
DRAWTEXT(REF(BDDW,15),25,'缩量幸福池'),COLOR00FFFF;

引用:

公式名称: 热点五星
适用软件: 大智慧L2
发 表 人: 一品茶缘     
发表日期: 2007-06-04
发表网址: http://www.chcj.net/redirect.php ... 515&ptid=616381

引用:

大盘大跌,好股难寻;闲来无事,随意编写,聊备参考.----{热点五星}


{热点五星----创幻论坛一品茶缘整理，大智慧L-2版本副图}
{热点五星指标使用方法：
盘面热点选五星，随时调整跟行情；
同比提示看业绩，热门好票好拉升。}
DRAWTEXTREL(10,50,''+STKLABEL+' '+STKNAME),LINETHICK1,COLOR00FF00;
ZYTB:=FINANCE2(11);JLTB:=FINANCE2(10);
DRAWTEXTREL(200,50,'■主营同比:'+NUMTOSTRN(ZYTB,2)+'%'),COLORFFFFFF;
DRAWTEXTREL(380,50,'■净利同比:'+NUMTOSTRN(JLTB,0)+'%'),COLORFFFFFF;

奥运概念:(STRFIND(BKNAME,'奥运',1)>0),COLOR00FFFF,POINTDOT,LINETHICK0;
整体上市:(STRFIND(BKNAME,'整体上市',1)>0),COLORFF00FF,POINTDOT,LINETHICK0;
定向增发:(STRFIND(BKNAME,'定向增发',1)>0),COLOR00FF00,POINTDOT,LINETHICK0;
预盈预增:(STRFIND(BKNAME,'预盈预增',1)>0),COLOR0000FF,POINTDOT,LINETHICK0;
基金重仓:(STRFIND(BKNAME,'基金重仓',1)>0),COLORFFFF00,POINTDOT,LINETHICK0;
DRAWTEXTREL(10,250,'■热点提示:'+'关注板块'),COLOR0000FF;
DRAWTEXTREL(10,450,'■奥运概念:'+NUMTOSTRN(奥运概念,2)),COLOR00FFFF;
DRAWTEXTREL(200,450,'■整体上市:'+NUMTOSTRN(整体上市,2)),COLORFF00FF;
DRAWTEXTREL(380,450,'■定向增发:'+NUMTOSTRN(定向增发,2)),COLOR00FF00;
DRAWTEXTREL(560,450,'■预盈预增:'+NUMTOSTRN(预盈预增,2)),COLOR0000FF;
DRAWTEXTREL(740,450,'■基金重仓:'+NUMTOSTRN(基金重仓,2)),COLORFFFF00;
DRAWTEXTREL(10,800,'所属板块:'+BKNAME),COLORFFFFFF;
AA:=DISPSTATUS=2;
STICKLINE(C*AA,0,10,8,0),COLOR0000FF;
DRAWTEXT(奥运概念*AA,10,'★'),COLOR00FFFF;
DRAWTEXT(整体上市*AA,8.5,'★'),COLORFF00FF;
DRAWTEXT(定向增发*AA,7,'★'),COLOR00FF00;
DRAWTEXT(预盈预增*AA,5.5,'★'),COLORFFFFFF;
DRAWTEXT(基金重仓*AA,4,'★'),COLORFFFF00;

引用:

一品注:{热点五星},只是为了便于盘中简单参考,没有太大意义----重要的是你自己要能根据盘面热点,及时对指标内的热点板块名称提示进行修改\变换,才有参考价值.大家随意看看吧.

[ 本帖最后由 蓝鼠 于 2008-3-27 11:52 编辑 ]